A Guide to Mage Macros
This is my best attempt to consolidate and organize the commonly used macros currently available for mages. The previous thread on mage macros is long out-of-date, so I'm sure this will be more useful. I'm not looking to include all the information Karite did on slash commands and addons, just macros. Hopefully anyone reading this will find what they're looking for, or have their own ideas to contribute. Additions and revisions are welcomed! Please reply if you've got something to add, or a better coded version of anything you see here.

In the interest of simplicity, I've tried to offer only one or two options for many of these macros. Also, my own press-or-click preferences for certain spells are evident in the macros I've included. If you would rather use modifier keys where I chose mouse buttons, or vice versa, swap [button:2] for [modifier:alt] anywhere you'd like. Also, I use example spells & items rather than a <Spell Name> argument; if you're concerned about the exact name of your spell or item, you can link it into your macro instead of mine (by shift-clicking the item or button in your spellbook). If you want other subtle changes, check out Cogwheel's Macro guide, linked as a resource below.

Post count capped again! I'm sad I didn't get my own 500th reply.

Before the Storm & The Burning Crusade & Changes to Macro Writing
Blizzard introduced significant changes to the WoW API shortly before the Burning Crusade expansion went live. The changes included a complete retooling of macro syntax. Many functions which were complex before have become very easy to program, but several previously useful mage macros were disallowed. The stated intent of the changes was to prevent macros and addons from making intelligent decisions, so that players would be responsible for when and what spells were used, and who the targets would be.
Previously, /script logical commands were available to automatically speed up decision making. The 2.0 changes protected many of these functions, disabling addons and macros which called them. Any macros which relied on checking you or your target's Buffs, Debuffs, Health, Mana, Range, Spell Cooldowns, and many other options are no longer possible.
While we lost some competitive edge from these changes, many alternatives have been introduced to make implementing our own decisions much easier.

Sources & Resources
Those new to using macros (or programming in general) would benefit from a read through Cogwheel's Macro Intro & FAQ (now including a discussion of conditional options) at
http://forums.worldofwarcraft.com/thread.html?topicId=2366703212&sid=1

Another great resource for macro, addon, and script information of all sorts is http://www.wowwiki.com

Information and ideas included in this guide have also been taken from the following sites. My thanks are due to these authors and contributors.
http://forums.worldofwarcraft.com/thread.html?topicId=12021348&sid=1
http://forums.wow-europe.com/thread.html?topicId=93909906&sid=1
http://wow-en.curse-gaming.com/wiki/mage-macro-guide/
http://magewiki.wikispaces.com/Macros

Contents

1. Offensive Macros

Spammable Arcane Missiles

Interrupt Ice Lance

Opener Pyroblast

Modifier Pyroblast

Frostbolt(Rank 1) Kiting

Stealth Breaker Arcane Explosion

One-Button Blizzard/Flamestrike

Castsequence Attack Routine

Friendly Fire Targeting

Cooldown Burners

I.W.I.N Buttons
--Berserking & MQG
--PoM AP Trinket Pyroblast

Pet Tricks, the Water Elemental and you.
--Spammable Summon & Attack
--Summon & Freeze
--Dismiss (& Invisibility)
--Modifier Nova
--On Demand Shatter
--Just Die Already

2. Defensive Macros

Blink & Look

Decurse

Interrupt Counterspell

Focus Counterspell

Your Favorite Harmless Animal, Polymorph
--Polymorph: Focus
--Polymorph: Spam
--Polymorph: Random
--Polymorph: Target Alert

Shapeshifting, Ice Cube Form
--Breakable Ice Block
--Ice Block/Cold Snap
--Break & Counterspell
--Block’n’Blink

One-Button Wards

Ice Barrier & Mana Shield

Self-Bandaging

3. Utility Macros

All-in-One Mana Gems

Evocation

All-in-One Food & Water

Smart Dampen/Amplify

Self Buff Sequence

One-Button Armor

One-Button Portal

One-Button Teleport

High Level Portal & Teleport

4. Keybinding 201

SetBindingMacro
--Macro
--Bind
--Save

SetBindingSpell

Last Updated 5-16-08
Added "Just Die Already" to water elemental macros, to correct the death bug in patch 2.4.2.

I've been ignoring this pretty much completely since it post capped. If you feel something needs to be updated that I haven't paid attention to, feel free to get in touch in game or via my guild website.

Offensive Macros

Spammable Arcane Missiles
This macro prevents you from interrupting an Arcane Missiles cast by recasting too early.

/cast [nochanneling:Arcane Missiles] Arcane Missiles

Interrupt Ice Lance
Mostly for Frostbite mages, this macro stops whatever spell you were casting and casts Ice Lance.

/stopcasting
/cast Ice Lance

Opener Pyroblast
This macro casts Pyroblast when you’re pulling. If you’re in combat, it casts Fireball.

/cast [nocombat] Pyroblast; Fireball

Modifier Pyroblast
For those with 8/8 Netherwind or similar proc PoM effects, this will ordinarily cast Fireball, but will use Pyroblast instead if you hold Alt. Because of latency, you won’t be able to cast as fast as possible and make use of this. The same was true of old automatic NW macros anyway.

/cast [mod:alt] Pyroblast; Fireball

Frostbolt(Rank 1) Kiting
Hold alt for the fast casting snare, or cast your maximum rank.

/cast [mod:alt] Frostbolt(rank 1); Frostbolt

Stealth Breaker Arcane Explosion
On a normal key press or click, the first macro casts Arcane Explosion (maximum rank), but on a right click it uses Rank 1. The second option automatically downranks if you're out of combat.

/cast [btn:2] Arcane Explosion(Rank 1); Arcane Explosion


/cast [nocombat] Arcane Explosion(Rank 1); Arcane Explosion

One-Button Blizzard/Flamestrike
Click for Blizzard, or alt-click for Flamestrike.

/cast [mod:alt] Flamestrike; Blizzard

Castsequence Attack Routine
This is a cast sequence designed for mana efficiency - three Scorches and an Arcane Blast. It will reset to Arcane Blast if not pressed for 7 seconds (at least enough time for the debuff to begin to fade).

/castsequence reset=7 Arcane Blast, Scorch, Scorch, Scorch, Scorch

Friendly Fire Targeting
Replacing spells with this macro will cause you to cast them at your target’s target if you’re targeting a unit which cannot be attacked.

/cast [harm] [target=targettarget] Fireball

Cooldown Burners
Automatically casting spells or using trinkets whenever they are cooled down can still be done, if the spells don’t cause a global cooldown when activated. However, any time the trinket or spell is not ready, error text is displayed, error speech is triggered, and the “spell failed” sound effect is played. More complex scripts can remove the text, but I have not found a way to remove the failure sound. Regardless, here are two such macros.

/use Zandalarian Hero Charm
/stopcasting
/cast Fireball


/cast Combustion
/stopcasting
/cast Fireball

I.W.I.N Buttons
These are a number of macros to instantly activate spell enhancers and cast your attack. First, the troll only berserking & haste trinket combo…

/use Mind Quickening Gem
/stopcasting
/cast Berserking
/stopcasting
/cast Fireball

…and the classic Presence of Mind, Arcane Power, and trinket macro.

/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use Vengeance of the Illidari
/stopcasting
/cast Pyroblast

NOTE: There's a slight problem with this one. You can't use it while running. Well, you can, but you have to click twice. Every line evaluates at the same time, so the /cast Pyroblast part cancels itself and gives you an error message at first. A second press will launch it (because you'll already have PoM active when it tests conditions). This is the best approach to this kind of macro, because it's 1 push if standing, 2 if running. Sorry about the limitations of the language.

Pet Tricks: the Water Elemental and you.
Spammable Summon & Attack – This will summon your pet, and if pressed again, will set it to attack your target ones the lag on summoning finishes. Spamming is okay, and won’t cause your pet’s first waterbolt to cancel and restart.

/cast [nopet] Summon Water Elemental
/stopmacro [target=pettarget, exists]
/petattack

Summon & Freeze – Summons or activates the ranged frost nova power, Freeze.

/cast [nopet] Summon Water Elemental; Freeze

Dismiss (& Invisibility) – You can use this script to dismiss your pet without using the pet dropdown menu. This particular macro dismisses him and begins your Invisibility fade, so he won't force you into combat unintentionally.

/run PetAbandon()
/cast Invisibility

Modifier Nova – Here's a slick little macro to cast Frost Nova if your elemental isn't out, and freeze if it is. To force a Frost Nova cast with the elemental is available, hold any modifier key. The scripting on the second line makes sure that you don't get Freeze locked onto your cursor when your elemental has expired.

/cast [nopet] [pet, mod] Frost Nova(Rank 1); [pet, nomod] Freeze
/run if not GetPetTimeRemaining() then ClearCursor() end

On Demand Shatter – With your pet out, you can use this macro to start a frostbolt cast and bring up the targetting circle for Freeze. Drop the pet's nova on your target just before the cast goes off for a nice suddent Shatter.

/stopcasting
/cast [pet] Freeze
/cast Frostbolt

Just Die Already – The 2.4.2 patch introduced a bug which causes elementals to leave a body for about 10 seconds after despawning. This prevents re-summoning, which can be extremely inconvenient. To fix this problem, add these two lines to the bottom of any of your elemental macros. If you hit it while the thing is dead but no despawned, it will dismiss it - removing your pet bar and allowing you to summon again.

/stopmacro [target=pet, nodead]
/script PetDismiss()

Defensive Macros

Blink & Look
Stops any cast or channel and Blinks you forward instead. Then, if your target is an enemy, flips your camera angle 180 degrees. Macroes cannot turn your character, only the camera, so a two-button mouse move will be needed to face your attacker again.

/stopcasting
/cast Blink
/stopmacro [noharm]
/run FlipCameraYaw(180)

Decurse
A reasonable replacement for the defunct decursive addon, hitting this button will remove a curse from whoever’s unit frame or 3D figure your cursor is hovering over. If your mouse is over a hostile or no target, you’ll decurse yourself.

/cast [target=mouseover, help] [target=player] Remove Lesser Curse

Interrupt Counterspell
Stops what you’re casting to immediately cast Counterspell.

/stopcasting
/cast Counterspell

Focus Counterspell
Uses the Alt modifier to CS your focus, rather than your target. I find this one very useful for bosses who need to be interrupted while DPSing elsewhere.

/cast [mod:alt, target=focus, exists, nodead] [] Counterspell

Your Favorite Harmless Animal, Polymorph
Polymorph: Focus – Sets your focus to your target and polymorphs it with a left click. Sheeps your focus without changing targets if you right click.

/cast [button:2, target=focus] [] Polymorph
/focus [nobutton:2]

Polymorph: Spam – Polymorphs your target, gives it the Star raid icon, sets it as your focus, and announces to your party or raid group your intention to sheep the <level> <gender> <race> target. How’s that for a chat spamming polymorph announcement?

/cast Polymorph
/focus
/run SetRaidTarget("focus", 1)
/run if UnitSex("target")==1 then g="female " else g="male " end;s="I'm going to sheep a "..g..UnitLevel("target").." %T";c="Party";if GetNumRaidMembers()>0 then c="raid" end;SendChatMessage(s,c)

Polymorph: Random – This macro randomly chooses the harmless animal your enemy will some impersonate.

/castrandom Polymorph, Polymorph(Rank 1: Pig), Polymorph(Rank 1: Turtle)

Polymorph: Target Alert - This script will whisper any member of your party who is targetting your target. Click it before or while sheeping to help clear things up.

/run u=UnitIsUnit;c="Party";t="Target";for i=0,40 do if not u(c..i,"player") then if u(c..i..t,t) then n,r=UnitName(c..i) SendChatMessage("I am Polymorphing your target!","WHISPER",this.language,n) end end end

Shapeshifting, Ice Cube Form
Breakable Ice Block – A 1.5 second “dead time” on toggle buttons like Ice Block was implemented to prevent unintentionally canceling buffs by spamming. This macro will restore previous functionality so Ice Block can be used to cancel debuffs almost instantaneously.

/cancelaura Ice Block
/cast Ice Block

Ice Block/Cold Snap – A macro allows rapid recasting of Ice Block by incorporating Cold Snap. The reset should be changed to 240 for Ice Floes.

/cancelaura Ice Block
/castsequence reset=300 Ice Block, Cold Snap

Break & Counterspell – This breaks Ice Block and immediately Counterspells your target.

/cancelaura Ice Block
/cast Counterspell

Break’n’Blink – This breaks Ice Block and immediately Blinks you forward.

/cancelaura Ice Block
/cast Blink

One-Button Wards
Left click for Fire Ward, right click for Frost Ward

/cast [btn:2] Frost Ward; Fire Ward

Ice Barrier & Mana Shield
This cast sequence will use a single button to cast Ice Barrier, then Mana Shield. If only Ice Barrier is cast, it will reset to Ice Barrier again in 30 seconds (reset should be changed to 24 for Ice Floes). The problem is, this isn’t a real cooldown test, it’s just a counter from the previous button push. Casting Mana Shield will move the sequence back to Ice Barrier, even if it is not yet ready. Adding another Mana Shield to the sequence would stop the pseudo-cooldown timing, by not pushing to Ice Barrier until 30 seconds after the Last mana shield cast.

/castsequence reset=30 Ice Barrier, Mana Shield

Self-Bandaging – Although this one doesn’t actually involve a mage spell, it is extremely useful. If your target can be healed, you bandage it, otherwise you bandage yourself (without losing your target).

/use [help] [target=player] Heavy Netherweave Bandage

Utility Macros

Mana Gems
This macro sequentially conjures all your mana gems on right clicks, and uses the highest level one available on left click. As a fall-through macro, this will cause error messages when used to consume gems.

/castsequence [button:2] reset=120 Conjure Mana Emerald, Conjure Mana Ruby, Conjure Mana Citrine, Conjure Mana Jade, Conjure Mana Agate;
/stopmacro [button:2]
/use Mana Emerald
/use Mana Ruby
/use Mana Citrine
/use Mana Jade
/use Mana Agate

Evocation
Left clicking equips your Intellect weapons & casts Evocation. Right Click equips DPS weapons.

/cast [btn:1] Evocation
/equip Amani Divining Staff
/equip Carved Witch Doctor's Stick
/stopmacro [btn:1]
/equip Tempest of Chaos
/equip Chronicle of Dark Secres
/equip Wand of the Forgotten Star

Food & Water – This macro has you eat and drink with a click, conjure water with shift-click, conjure food with shift-right-click, and cast a Ritual of Refreshment with Alt-Click.

/use [nomod] Conjured Manna Biscuit
/use [nomod] Conjured Glacier Water
/use [nomod] Conjured Croissant
/cast [mod:shift, btn:2] Conjure Food;[mod:shift] Conjure Water;[mod:alt] Ritual of Refreshment

Smart Dampen/Amplify
Left clicks Dampen Magic, right clicks Amplify; if your target is in your party, it buffs him, otherwise it buffs you instead.

/cast [btn:2, party] [btn:2, target=player] Amplify Magic;[party] [target=player] Dampen Magic

Self Buff Sequence
Insert your own favorite soloing buffs, and press one button three times to cast them.

/castsequence [target=player] reset=600 Dampen Magic, Arcane Intellect, Molten Armor;

One-Button Armor
Click for Mage Armor, right click for Molten Armor, alt-click for Ice Armor.

/cast [mod:alt]Ice Armor; [btn:2]Molten Armor; Mage Armor

One-Button Portal
Useful for those below level 65 to get around and help their friends get around. Click to portal to Ironforge (Orgrimmar), alt for Stormwind (Undercity), control for Darnassus (Thunder Bluff), and shift for Exodar (Silvermoon).

/cast [mod:shift] Portal: Exodar; [mod:alt] Portal: Stormwind; [mod:ctrl] Portal: Darnassus; Portal: Ironforge

/cast [mod:shift] Portal: Silvermoon; [mod:alt] Portal: Undercity; [mod:ctrl] Portal: Thunder Bluff; Portal: Orgrimmar

One-Button Teleport
Here’s the same thing as the Portal macro, but just for you. It’s not useful past level 59.

/cast [mod:shift] Teleport: Exodar; [mod:alt] Teleport: Stormwind; [mod:ctrl] Teleport: Darnassus; Teleport: Ironforge

/cast [mod:shift] Teleport: Silvermoon; [mod:alt] Teleport: Undercity; [mod:ctrl] Teleport: Thunder Bluff; Teleport: Orgrimmar

High Level Portal & Teleport
Once you’re level 65, this will get you anywhere. Click for portal, right click for teleport. This one’s even the same for Horde and Alliance.

/cast [btn:2] Teleport: Shattrath; Portal: Shattrath

Keybinding 201

For any number of reasons, players often want to get a spell off thier actionbar, and just keep it forever hotkeyed somewhere. The basic keybindings interface doesn't give all the options you have, so here's a guide to getting what you want out of your keyboard.

First, you can use a number of actionbar addons to specifically set bindings for the buttons on those bars. From my experience with Bongos, this is a pleasantly intuitive way to set things up. Unfortunately, the binding per button stay the same when the actionbar pages, so if you're on page 2, you won't have the same custom binding to page 1 unless you copied the spell/macro onto every page.

Alternatively, you can use script commands to set permanent key bindings for your spells or macros. This one means you can set Blink to always be "R" regardless of actionbar page, or where you have it on any given bar (if it's there at all). The down side is, it's much more difficult to keep track of all your custom bindings. With great power comes great responsibility or something...

-----

On page 10, Valcore asked to make his middle mouse button polymorph & focus a target, and resheep his focus if he held alt. This seems like a great example, so I'm going to walk through setting it up.

The first step is to make yourself a macro with the logic you want, and name it something unique.
In this case we'll have to modify the Polymorph:Focus macro to use a modifier, rather than a right click. This will be a common modification as you set up macros to bind, since right clicking a mouse button or the F7 key just isn't an option.
We'll need to use the name of this macro to bind it, I'm going to call this one Sheeper.

/cast [modifier:alt, target=focus] Polymorph; Polymorph
/focus [nomodifier:alt]

Select the key you want bound, and run the SetBinding command.
Here we're binding this to middle mouse, and the macro we're using is Sheeper, so the command to run is:

/run SetBindingMacro("BUTTON3", "Sheeper")

Middle Mouse button ("BUTTON3") is an odd case, ordinarily you can use a single letter "H", function key "F7", or a modified key "CTRL-H". Remember, this script is run as-is. The quotes are important to keep when you do your own bindings. Also, Control, Alternate, and Shift are not valid arguments to this function by themselves. These are reserved as modifier keys. Binding to CTRL-T would be fine, but a binding to only the ALT key won't work.

Save your work, unless you botched something bad.
Your keybindings aren't saved on logout, so we need to run one more thing before this will stay permanently. Here's your chance to play around for a little while, and make sure you didn't replace a binding you'll miss. It's also a good idea to make sure you typed everything right, by testing the new bind and the macro with it.
Once you're satisfied that things are working well, save your bindings. Ordinarily, you'll want this stuff to save for a single character. If you want to save your bindings for all the characters on your account, change the 2 to a 1.

/run SaveBindings(2)

------

Those paying really good attention might still be wondering if they have to blow a macro slot to get Blink on the "R" key. As I'm sure you'll be happy to know (and may have already guessed) there's a SetBindingSpell command you can use for that. You just need to supply the exact spell name (I'm honestly not sure if you have to include a rank) and the key you want to use.

/run SetBindingSpell("R", "Blink")
/run SaveBindings(2)

This section has been obsoleted by the introduction of the new latency busting cast mechanisms. The positive effects of /stopcasting macros are now embedded in all spells, without the downside of canceling casts due to poor timing or pushback.

---

Q u o t e:
I've been considering adding a post about this for a while, and with a recent thread on the topic hitting its post limit I think now is the time. Because of server/client mechanics, the amount of time between your spammed spellcasts is increased pretty significantly. By using the /stopcasting command with your main nuke, you lose the ability to spam the button, but you gain the ability to skillfully starts casts before the client UI would normally let you. This is a big DPS booster once you learn to play it right, and there are tools to help you.

Here's a slightly editted post by Falcore; the full, original text of which (along with testimonials) can be found at:
http://forums.worldofwarcraft.com/thread.html?topicId=105811473&sid=1

Blizzard puts a buffer on the cast bar to attempt to equalize the advantage of someone with good latency vs someone with bad latency. While the server takes a variable amount of time to register that your spell has been cast, your client (the cast bar you see), is a flat amount of time.

Proof: Have you ever wound up a frostbolt or fireball or whatever and perhaps jumped a split second before the cast goes off, yet it still goes? Or jumped to start flying on your mount before the cast bar expires?

Blizzard makes it so that you can not cast before that cast bar is done, but there is a way around it.

The way around this is the use of a "/stopcasting" macro.

For example for frost mages:
/stopcasting
/cast Frostbolt

Now, the problem with this is you cannot spam the button. When you hit the button, it will stop whatever cast you are currently casting and it will begin to cast the next frostbolt. If you hit it too early, it will cancel your current cast! So get ready to stop spamming your buttons.

I can't stress enough that this is difficult to adjust to, because if you spam, or jump the gun, you'll cancel your previous cast, and lose DPS. To avoid doing this, you just need practice, but you can also use a mod to give you a more detailed casting bar (it's still an estimate, but it seems to work well enough). In the case of Scorch spam (where the change in DPS is extremely pronounced) you can watch the global cooldown as your timer to repress. The CD will end before your cast bar, but the GCD is enough time for your Scorch to have fired.

While I really dislike pointing to addons, I think one is worth mentioning for this. II'll leave it in Falcore's words, so if you hate it you can't flame me!

Ok, next part is to get a mod called Quartz, which can be found on the WoWAce website. This mod will take the place of any cast bar you are currently using. What it will do is look at your latency and then mark your cast bar accordingly with a "red" section in it. The higher your latency, the longer the red part will be. The bar still shows the 2.5 second (frostbolt, 3 for fireball) length, but there will now be a varying amount of red on the bar.
All you have to do is hit your next frostbolt the split second that your bar reaches the red section of the bar.

This interface change will remind many of the defunct, FastCast addon, which did effectively the same thing, but allowed you to spam. Because a mod can no longer decide when to cast a spell for you (based on it's cooldown or whatever else) you need to adapt to watching the bar colors on your own.

And for reference, here are a handful of nuke macros to use.

This one's for Frostbolts, and will cast Rank 1 for the snare if you hold Alt.

#showtooltip
/stopcasting
/cast [modifier:alt] Frostbolt(Rank 1); Frostbolt

And this one's for Fireball, casting Scorch for you debuff refreshment pleasure when you hold Alt.

#showtooltip
/stopcasting
/cast [modifier:alt] Scorch; Fireball

I use the inverted version, casting Fireball on Alt, and Scorch normally.

#showtooltip
/stopcasting
/cast [modifier:alt] Fireball; Scorch

I'm not sure how this tactic works for channelled spells, but if you want to try things out, the basic code for any spell is very simple (as in Falcore's post). Just replace with the spell you want.:

/stopcasting
/cast Arcane Blast

-----

For those who might doubt the legitimacy of these tactics, I point you to the UI Pirate, Slouken...
http://forums.worldofwarcraft.com/thread.html?topicId=388011140&sid=1

---

An ounce of prevention is worth a pound of cure.

first!
great post!

BLUE ----> Sticky PLS!

Sticky it indeed, i for one couldnt use a macro to save my life :P

I love you.

omg

/salute

TYTYTY =P

Fantastic... I could almost replace Cryolisis with these.

begging for /sticky.

Finally a workable ice barrier/mana shield macro. TY sir!

a few more

Wards
#showtooltip
/cast [modifier:alt] Fire Ward; Frost Ward
OR
/cast [button:1] Fire Ward; [button:2] Frost Ward


Flame Strike/ Blizzard
#showtooltip
/cast [modifier:alt] Flame Strike (rank x); Blizzard (rank x)
OR
/cast [button:1] Flame Strike (rank x); [button:2] Blizzard (rank x)

FrostBolt PvP
#showtooltip
/cast [button:1] Frostbolt (rank x); [button:2] frostbolt (rank 1)

Have not tried this one.
Dismount . Poly
#showtooltip Polymorph
/dismount [mounted]
/cast Polymorph

Reported for sticky :)

Tag!!!
Awesome post!
11/10

I use this to sheep then cast detect magic, in case it's a fel lock and you want them to devour the detect magic instead of the poly.

Its obviously very situational but I find easier than hunting down the detect magic hotkey. It could also be changed so that you use modifier: shift command.

/castsequence [harm] polymorph, detect magic

Bookmarked -- and that's saying something.