Here is Version 2 of my Warlock macro thread, completely compatible with WoW 2.1.0. It is a consolidated and hopefully easier to read version of my older thread. As always, if you have questions, concerns or new macros, please respond and I'll try to incorporate them into the original thread. Some of these macros were originally copied from Schoonmoeder on the EU forums, but most have been created by me or other warlocks on the US forums. As of patch 2.1.0, all of these macros are working.

Occasionally, there is more than one way to accomplish the same result. In these cases I have attempted to include a couple of different examples. If you modify any of the macros in order to suit your specific needs (that are not met by one of the current macros) please post your macro and I"ll incorporate it to the OP.

This macro thread was previously contained under the post "My Warlock Macros (2.0.3)" but was moved since I forgot to include reserved posts for expansion.
http://forums.worldofwarcraft.com/thread.html?topicId=65368294&sid=1

The following are some very useful threads in the Macros & UI forums. Most of the macros that I have created have used commands or information from one of the following posts.

Cogwheel's Complete Macro Guide
http://forums.worldofwarcraft.com/thread.html?topicId=96143900&sid=1


WoW 2.1.* changes - Concise List (v2)
http://forums.worldofwarcraft.com/thread.html?topicId=102909657&sid=1

Upcoming 2.2 Changes - Concise List
http://forums.worldofwarcraft.com/thread.html?topicId=102909678&sid=1



General Macro Information

If you set your macro icon to the ?, it will automatically pick the appropriate icon (and will change during /castsequence macros)

If you include #show at the begining of a macro, it will display the cooldown for the first listed spell. You can type the name of the spell in order to force it to show the cooldown for a particular spell, for example #show Death Coil

If you include #showtooltip at the beginning of a macro, it will display the cooldown and tooltip for the first listed spell. You can type the name of the spell in order to force it to show the cooldown and tooltip for a particular spell, for example "#showtooltip Death Coil". New in 2.1.0, the #showtooltip command now dynamically changes based on conditionals used within the macro.

If you do not include a rank after the name of a spell, it will automatically use the highest learned rank.

If you try to cast a buff on a player that is too low, it will automatically downrank that spell. (Not important for Warlocks, but if you modify these for other classes it's good to know.)

*As of WoW 2.0, all in-combat intelligent decision making has been removed from macros. This means that it is no longer possible to cast spell X based on race, class, health, buff, debuff, NPC/PC... pretty much anything that you would want to test on your target.*

The macros are divided into categories based on the school that the main spells commonly fall under. After the schools are listed macros that are universal for all Warlocks. Finally, after that are several handy modifications that can be added to almost any macro. Note that I always include the #showtooltip function in my macros. It is up to you whether you keep them in yours or not, removing that line will have no effect on the actual function of the macro.



Affliction

Memorized Fearing

Dotter

Drain Soul (With Imp Drain Soul and Soul Shard auto-delete)

One Button Draining for Dummies

Drain Life for Dummies

Amplified CoA/CoA - One button

Amplified Curse of Exhaustion

Life Tap/Dark Pact

Debuffer

Corruption Spam

Memorized Curse Of Recklessness/Curse of Weakness

Death Coil/Howl of Terror

Demonology

Memorized Seducing

Memorized Seducing without Focus

Memorized Fearing/Seducing

Devour Magic

Semi-Intelligent Devour Magic

Spell Lock

Voidwalker Shield/Fel Domination/Summon Voidwalker

Fel Domination Summoning/Soul Link

Pet Attack on Mouseover

Multipet All-in-One macro

Derstruction

Nuker

Immolate / Incinerate / Conflagrate

Immolate / Conflagrate 2

Max DPS Shadowbolt Spam

Miscellaneous

Create/Use Major Healthstone

Fire wand/Use/Create Spellstone

One-button Mounting/Dismounting

Random Mount Macro

Instancing for Dummies/While on the phone

Modifications

Error Free Trinketing

Commenting out lines

Toggling Pet Autocasts

Affliction
Most affliction macros deal with applying multiple DoTs to a target, or targeting multiple MOBs to apply DoTs to.


Memorized Fearing
* This macro will set your focus to a mob and fear it all in one click. If your focus dies, it will reset the focus and cast fear on the next mob that the macro is used with. If your focus is still alive, it will cast fear on your focus, no matter what your target is. You can force it to reset your focus to your current target by holding down alt while pressing the macro button. If your focus is somehow set to a help target, it will clear the focus and cast fear on your current target (but will not set the focus to that target). This macro will not automatically chain Fear, you must press the macro button for each individual fight.

#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/cast [target=focus,harm] [] Fear



Dotter - Instance order 1/non-dispelling PvP
* This will cast a different spell in the sequence each time the button is pressed. It will reset when you leave combat or change targets. This has UA last, and allows you to cast 3 of your 4 dots while on the move, and regain health from SL at an early stage. This macro will cast Amplify Curse if you hold down alt.

#showtooltip
/cast [modifier:alt] Amplify Curse
/stopcasting [modifier:alt]
/castsequence reset=Target/Combat Corruption, Siphon Life, Curse of Agony, Unstable Affliction



Dotter - Instance order 2
* This is the same as the above, except that it casts your 2 most damaging instant DoTs immediately.

#showtooltip
/cast [modifier:alt] Amplify Curse
/stopcasting [modifier:alt]
/castsequence reset=Target/Combat Corruption, Curse of Agony, Siphon Life, Unstable Affliction



Dotter - Grinding
* This is the same as the above, except that it casts your only casting time DoT to start. This is recommended when grinding. As you can see, the order of the spells is simple to change, and can be changed to match your personal preference. I have listed these 3 orders because I have received questions/complaints in the past about why it was listed in order a instead of b....

#showtooltip
/cast [modifier:alt] Amplify Curse
/stopcasting [modifier:alt]
/castsequence reset=Target/Combat Unstable Affliction, Corruption, Curse of Agony, Siphon Life



Drain Soul (With Imp Drain Soul and Soul Shard auto-delete)
*This macro will cast rank 1 Drain Soul so that you receive your +15% mana. As of 2.1.0, it does not matter whether you or your pet get the killing blow, as such the /petfollow was removed. The Soul Shard auto-delete is courtesy of Vico. This macro deletes the 27th and 28th items in the 4th bag slot while casting drain soul. For me, that is always a 28 slot soul shard bag. With this macro, I tend to always be at 27 shards. Saves the tedium of having to manually delete soul shards, while allowing me to drain soul all I want for mana. Change the numbers as you see fit for the position and size of your soul shard bag.

#showtooltip
/cast [nochanneling:Drain Soul] Drain Soul(Rank 1)
/script PU = PickupContainerItem; D = DeleteCursorItem; PU(4,27); D();PU(4,28); D();



One Button Draining for Dummies
*This macro will cast Drain Life without any buttons held, drain soul with alt held, and mana with ctrl. It will interupt the channel to channel a different spell, but not the same spell. ie. you can interupt drain life with drain soul, but not with a second drain life. Since your pet commands are automatically mapped to ctrl 1-9, you may need to either re-map them or use a modifier other than ctrl.

#showtooltip
/cast [nochanneling:Drain Soul, modifier:alt] Drain Soul; [nochanneling:Drain Mana, modifier:ctrl] Drain Mana; [nochanneling:Drain Life, nomodifier] Drain Life;



Drain Life for Dummies
*Drain life, doesn't cast drain life when already channeling it, therefore this button is spammable.

#showtooltip
/cast [nochanneling:Drain Life] Drain Life



Amplified CoA/CoA - One button
*This macro will cast Amp'd CoA if you hold down alt, normal CoA if you dont.

#showtooltip
/cast [modifier:alt] Amplify Curse
/stopcasting [modifier:alt]
/cast Curse Of Agony



Amplified Curse of Exhaustion
*This macro will cast an Amplified Curse of Exhaustion on your target if Amp Curse is up, or a normal one if it isn't. Note that Exhaustion and Agony may be interchanged in either of the Amplify Curse macros in order to achieve the functionality you desire.

#showtooltip Curse of Exhaustion
/cast Amplify Curse
/stopcasting
/cast Curse of Exhaustion
/stopcasting



Life Tap/Dark Pact 1
*This casts Life Tap, or Dark pact with alt held down, or a lower version of Lifetap with ctrl held down (so that you dont over-tap as much)

#showtooltip
/cast [nomodifier] Life Tap; [modifier:alt] Dark Pact ; [modifier:ctrl] Life Tap (Rank 3)



Life Tap/Dark Pact 2
*This macro will cast Dark Pact if you have an imp summoned, or lifetap otherwise. You can force it to cast Life Tap by holding down any modifier, even if an imp is summoned.

#showtooltip
/cast [pet=imp, nomodifier] Dark Pact; Life Tap



Debuffer
*This macro will cast Curse of Shadows without any modifiers, Curse of Elements with alt held down, and Curse of Weakness with ctrl held down.

#showtooltip
/cast [modifier:alt,harm] Curse of the Elements; [modifier:ctrl,harm] Curse of Weakness; [harm] Curse of Shadows



Corruption Spam
*This macro will target enemies sequentially and cast rank 1 corruption on them (for messing up with cleansing and getting NF procs). Just keep spamming this button to cast on everyone.

#showtooltip
/targetenemy
/cast Corruption(Rank 1)



Memorized Curse Of Recklessness/Curse of Weakness
*This macro is great in instances (heroics) when you need to be in firm control of your fears. It will cast Curse Of Recklessness on your focus without any modifiers, and Curse of Weakness with any modifier. This will cause your focus to ignore the fear when CoR is on it and run towards you (and away from that group it was about to pull), and immediately be feared when CoW is applied. You could add (Rank 1) after the CoW, in order to save mana, but I prefer the highest rank possible as it tends to help save my squishy self if I don't get the CoR off again (or if fear breaks). Use this macro in conjunction with the Memorized Fearing (or Memorized Fearing/Seducing) macro listed above.

#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/cast [target=focus,exists,harm,nomodifier] Curse of Recklessness(Rank 1); [target=focus,exists,harm] Curse of Weakness



Death Coil/Howl of Terror
*This is a space saving macro that will cast Death Coil, or Howl of Terror with alt held down.

#showtooltip
/cast [modifier:alt] Howl of Terror; Death Coil

Demonology
These macros deal with pet related abilities and talents granted from the demonology tree.



Memorized Seducing
*Same as the fearing macro, except for your succubus

#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/cast [pet:succubus,target=focus,exists,harm] [] Seduction



Memorized Seducing without Focus
*this macro will seduce your target, and reseduce it again and again no matter what your target is. It does NOT use /focus at all, and so is compatible with the Memorized Fearing macro listed above. The macro will cast Searing Pain if you hold down any modifier, in order to cause the mob to attack you and not your succubus.

NOTE: This macro must be clicked twice the first time it is used, and as such I would not recommend it as your primary seduce macro, but as one that is useable when you are fearing and seducing at the same time.

#showtooltip
/petattack [target=pettarget, noexists]
/cast [target=pettarget, modifier] Searing Pain
/cast [target=pettarget, harm] Seduction


Memorized Seducing part 3
*Seduce leftclick and reseduce with rightclick without having to switch targets. This is another method of doing memorized focus seducing. I have not extensively tested it, bu tit should work if you are having problems with the other seduce macros. Left click to set your target, right click to reseduce the same target.

/target [button:2] focus
/clearFocus
/focus [harm] target
/cast [target=focus,exists,pet:Succubus] Seduction
/targetLastTarget [button:2] 2


Memorized Fearing/Seducing
*This will seduce your focus if you have your succubus out, fear if you dont, or fear your current target if you hold ctrl (regardless of focus).

#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists];[target=focus,dead]
/clearfocus [target=focus,help]
/cast [modifier:ctrl]Fear; [pet:succubus,target=focus,harm]Seduction;[target=focus,harm]Fear;[pet:succubus]Seduction;Fear



Devour Magic
*This macro will devour magic from yourself if you hold alt, your target otherwise.

#showtooltip
/cast [pet:Felhunter,target=player,modifier:alt] Devour Magic; [pet:Felhunter] Devour Magic



Semi-intelligent Devour Magic
If my target is friendly, he gets dispel priority over my mouse- over target (if he's friendly), who gets dispel priority over me, who gets dispel priority over the felhunter himself. Finally, the macro will devour off your current target if all else fails (to be used offensively)
/cast [help] Devour Magic; [target=mouseover,help] Devour Magic
/cast [target=player] Devour Magic
/cast [target=pet] Devour Magic
/cast Devour Magic


Spell Lock
*This macro will Spell Lock your pets target if he has one, or yours if he doesnt.
#showtooltip
/cast [target=pettarget, harm] [] Spell Lock


Voidwalker Shield/Fel Domination/Summon Voidwalker
*This will Sacrifice your VW, Cast Fel Domination, and then summon another VW. Will only work in combat.

#showtooltip
/stopmacro [nocombat]
/stopmacro [nopet:voidwalker]
/cast [pet:voidwalker] Sacrifice
/cast fel domination
/stopcasting
/cast summon voidwalker



Fel Domination Summoning/Soul Link
*This macro will summon your imp with a normal cast. If you already have an imp summoned, it will cast Soul Link. If you are in combat and have any pet OTHER than the imp (which is alive), it will cast Fel Domination and summon the imp. You can force the macro to not cast Fel Dom by holding down any modifier key. This macro can be changed for your other pets by replacing the pet:imp and Summon Imp with the appropriate pets (felhunter, felguard, voidwalker, succubus).

#showtooltip
/cast [pet:imp,nodead] Soul Link
/cast [combat,nomodifier] Fel Domination
/stopcasting [combat,nomodifier]
/cast Summon Imp


Pet Attack on Mouseover
*This macro is useful for getting your Felguard (or other pet) to attack whatever your mouse is hovering over when you press the macro button. Great when you want to have your pet attack something, but dont want to swap targets yourself.

#showtooltip
/petattack [target=mouseover,harm]


Multipet All-in-One macro
This macro will do the most common actions for each pet. Modified from one by Serick on Page 4. It will cause the VW to attack your target (for grinding). It will also... Devour Magic off yourself with alt, or your target without; Seduce your target; Sacrifice a VW with alt held; Dark Pact an imp; and Intercept with a FG out.

#showtooltip
/cast [pet:felhunter,target=player,modifier:alt] [pet:felhunter] Devour Magic; [pet:succubus] Seduction; pet:voidwalker, modifier:alt] Sacrifice; [pet:imp] Dark Pact; [pet:felguard] Intercept
/petattack [pet:voidwalker]

Destruction
These macros deal mainly with direct damage spells, and spells gained through the destruction tree.


Nuker
*This is a space saving macro will cast Shadowbolt if pressed normally, Soul Fire with shift, Searing Pain with ctrl and Shadowburn with alt.

#showtooltip
/cast [nomodifier] Shadow Bolt; [modifier:alt] Shadowburn; [modifier:shift] Soul Fire; [modifier:ctrl] Searing Pain



Immolate / Incinerate / Conflagrate
*This is another space saving macro. If you hold down alt, it will cast Immolate, Conflagrate if you hold down ctrl, and Incinerate without anything. If you would like it to always show your Conflagrate cooldown, replace #showtooltip with #showtooltip conflagrate.

#showtooltip
/cast [modifier:alt] Immolate; [modifier:ctrl] Conflagrate; Incinerate



Immolate / Conflagrate 2
* I personally dont like this macro, since if you switch targets then go back to your original target it would cast immolate instead of conflag... but some people like it, so here it is.

#showtooltip
/castsequence reset=combat/target/15 Immolate, Conflagrate



Max DPS Shadow Bolt Spam
This macro will maximize your DPS of pure Shadow Bolt Spam. Note that this macro is NOT spammable, or it will keep canceling your spells. The reason for this macro is due to lag between you and the server, and the way that the UI handles this lag. By careful use of this macro (and possibly addiotional addons that measure lag), you can increase your DPS from 5-20%. This macro is designed to be pressed during that brief period of time between when the server registers a spell cast, and the client UI does. For a complete description, see...

#showtooltip
/stopcasting
/cast Shadow Bolt

Miscellaneous
These are a collection of macros that I found useful, but didn't fit within one of the other categories. Some of these are universal to all classes, or could be easily modified for another class (the healthstone macro into a food/drink macro for mages)



Create/Use Major Healthstone
*This macro creates a Master Healthstone if you hold alt, and uses it if you don’t. To set it for a different type of Healthstone, use a lower rank and a different name for the healthstone.

#showtooltip
/cast [modifier:alt] Create Healthstone
/use [nomodifier] Master Healthstone



Fire wand/Use/Create Spellstone
*This macro will create a Master Spellstone if you hold alt (but will not equip it), and either shoot with your wand or use the spellstone, depending on what you have equipped.

#showtooltip
/cast [modifier:alt] Create Spellstone
/stopmacro [modifier:alt]
/cast [equipped:wand] Shoot; Master Spellstone



One-button Mounting/dismounting
*This macro will summon your flying mount if you are in outlands, your Dreadsteed if you are not. You can force it to summon your dreadsteed instead of your flying mount if you hold down any of the modifiers. It will also dismount you if you are mounted. Change Ebon Gryphon with the name of your mount.

#showtooltip
/cast [nomounted,nomodifier,flyable] Ebon Gryphon; [nomounted] Summon Dreadsteed(Summon)
/dismount [mounted]



Random Mount Macro
*This is a macro that will mount you randomly on one of your mounts. Replace mount1, mount2... with the name of the mount that you want to use. This is useful as a lot of people currently have more than 1 pvp mount and would like to show off. Thanks to Rte for this macro.

#showtooltip Summon Dreadsteed
/castrandom [nomounted] mount1, mount2, mount3
/dismount [mounted]


Instancing for Dummies/While on the phone
*This is a macro that I just thought up while running a group through Hellfire Ramparts on my Druid. As usual, one member (also as usual, a hunter) kept attacking the wrong target and forcing me to be charging all over the instance trying to keep agro off him.
This macro will cast Shadow Bolt (or whatever other spell you put in...) on the target of your focus, no matter what your current target is; unless you hold down alt, at which point it will cast on your target. Set your focus (at the beginning of the instance) to your Main Assist or Main Tank with /focus. If you are planning on using this, DO NOT use the memorized Fear/Seduce macros or they will reset your focus. If this happens, this macro SHOULD cast Shadow Bolt on your current target (at least in 99% of the times)

#showtooltip
/cast [nomodifier, target=focustarget,harm] Shadow Bolt; [modifier:alt,harm] Shadow Bolt; [harm]Shadow Bolt

Modifications
These are modifications that can be added to any macro to improve/change them.


Error Free Trinketing
*This addition to any macro will attempt to use the trinket in your first trinket slot on every cast. The 2 /script lines temporarily disable the error message so that you don’t see a message every cast telling you that the trinket isn’t available yet (is on CD). Use /use 14 for your second trinket slot.

/script UIErrorsFrame:UnregisterEvent("UI_ERROR_MESSAGE");
/use 13
/script UIErrorsFrame:RegisterEvent("UI_ERROR_MESSAGE");

Commenting out lines
*If you change spec’s and no longer have access to some spells, but don’t want to delete your macro, just comment out the lines that you don’t want with a #. The following macro is changed into a simple Summon Imp macro by adding # to the beginning of the demonology talent lines.

#showtooltip
#/cast [pet:imp,nodead] Soul Link
#/cast [combat,nomodifier] Fel Domination
#/stopcasting [combat,nomodifier]
/cast Summon Imp


Toggling Pet Autocasts
This is a method for toggling pet autocasts on and off that can be added to any macro.

/click PetActionButton1 RightButton

reserved

reserved

reserved

sweet, good work :D

Is there a macro that will tell my pet to kill a grounding totem? Please only post if you have one that you have tested and know works properly. If you or anyone else has one I thank you very much.

---

Q u o t e:
Is there a macro that will tell my pet to kill a grounding totem? Please only post if you have one that you have tested and know works properly. If you or anyone else has one I thank you very much.

---

I haven't tested it since 2.1.0, but this used to work (and should still)

/petattack Grounding Totem

Also, for those times when a rogue is near (you've just killed him and are camping him for instance.. not that I condone corpse camping... unless it's a rogue!)

/petattack "rogue"
/target "rogue"
/cast Curse of Agony

Where "rogue" is replaced with the actual name of the rogue. If you spam this button, your pet (felhunter) will chase the rogue as soon as he rezzes, and you will target and hopefully cast CoA on him before he can stealth.

Keep the macros coming.

/bump

tag

Tibber,

Thank you once again for compiling such an awesome list of working macros :)

Problem - For some reason any modifier alt keys won't work or me and I'm unsure why :(

#showtooltip
/cast [nomodifier] Fear; [modifier:alt] Howl of Terror

Will cast fear no problem, but not howl of terror with alt pressed.

same with

/cast [modifier:alt] Immolate; Siphon Life

Siphon life works fine, but it wont cast Immo....

I use bongos 2 for my keys unsure if that has anything to do with it but would appreciate any help here if possible.

Thanks

Here are my versions of Banish/ReBanish and Seduce/ReSeduce. (you could make the same macro for any CC)

Seduce leftclick and reseduce with rightclick without having to switch targets:

/target [button:2] focus
/clearFocus
/focus [harm] target
/cast [target=focus,exists,pet:Succubus] Seduction
/targetLastTarget [button:2] 2


Banish leftclick and reseduce with rightclick without having to switch targets:

/target [button:2] focus
/clearFocus
/focus [harm] target
/cast [target=focus,exists] Banish
/targetLastTarget [button:2] 2

---

Q u o t e:
Tibber,

Thank you once again for compiling such an awesome list of working macros :)

Problem - For some reason any modifier alt keys won't work or me and I'm unsure why :(

#showtooltip
/cast [nomodifier] Fear; [modifier:alt] Howl of Terror

Will cast fear no problem, but not howl of terror with alt pressed.

same with

/cast [modifier:alt] Immolate; Siphon Life

Siphon life works fine, but it wont cast Immo....

I use bongos 2 for my keys unsure if that has anything to do with it but would appreciate any help here if possible.

Thanks

---

I have no idea what bongos 2 is, but that would be my guess :) Is it a keymapping to mousepad type thing? I had similar issue, where I had 2 of my mouse buttons mapped to ctrl-g and ctrl-h (in the logitech control panel) then bound 2 of my macros to ctrl-h and ctrl-g. It worked fine if I was using alt in the macro, but if I tried to use ctrl in there as well (see my memorized fearing/seducing macro) it didnt work unless I actually clicked on the hotbutton.

If so, and if bongos 2 is mapped to alt-letter keys, try remapping it. Does ctrl or shift work?

---

Q u o t e:
Here are my versions of Banish/ReBanish and Seduce/ReSeduce. (you could make the same macro for any CC)

Seduce leftclick and reseduce with rightclick without having to switch targets:

/target [button:2] focus
/clearFocus
/focus [harm] target
/cast [target=focus,exists,pet:Succubus] Seduction
/targetLastTarget [button:2] 2


Banish leftclick and reseduce with rightclick without having to switch targets:

/target [button:2] focus
/clearFocus
/focus [harm] target
/cast [target=focus,exists] Banish
/targetLastTarget [button:2] 2

---

Personally, I dont like macros that switch my target. I find if I use that, then I cant spam the reseduce when I know it is about to break (or think it has broken early in pvp) and cast a spell on another target at the same time. Is there any particular benefit to using /target then /targetlasttarget that you have found?

Tibber,

Ty for the reply. I think it was a bug in bongos, I disabled it and everything works fine..

you rock btw ty again <3